View source for Bài 6: Bật tắt đèn tự động bằng cảm biến ánh sáng sử dụng Arduino

== '''Mục tiêu''' ==

Qua <u>chuỗi 5 bài trước</u>, các bạn đã cùng mình đi qua từng bước tiếp cận những kiến thức Điện tử và kỹ thuật Lập trình Arduino cơ bản nhất rồi.

:Từ bài này, chúng ta hãy thử vận dụng những gì đã học được để làm những <u>dự án nhỏ thật tế</u> nhé.

:Mục tiêu bài này là làm một ''"Bộ bật tắt đèn tự động"'' đơn giản, có thể lắp đặt ở nhiều nơi, như: cầu thang, tủ quần áo, phòng ngủ, bàn làm việc, ...

:Các bạn đã sẵn sàng chưa, cùng đi nào!

== '''Kiến thức cơ bản''' ==

=== <span style=color:#314B9F>Cảm biến Quang trở?</span> ===

[[File:Lesson6-Photoresistor.png|300px|thumb|right|alt=Quang trở|Quang trở]]

:'''Quang trở (Photoresistor)''' là một loại linh kiện có chức năng khá giống '''Biến trở'''. Nó có thể thay đổi giá trị '''Trở kháng (Ω)''' theo <u>Cường độ ánh sáng</u> chiếu vào nó.

:Nó có thiết kế ''"Hình đĩa"'' và ra hai đầu dẫn, được cấu tạo chủ yếu từ thành phần chính là ''"Cadmium Sulfide" (một chất bán dẫn)''. Nên khi có ánh sáng chiếu vào bề mặt đĩa, chất này tiếp xúc với ánh sáng làm cho nhiều hạt '''Electron''' bị kích thích chuyển sang trạng thái <u>tự do</u> và có thể tham gia vào quá trình dẫn điện. → Kết quả là Trở kháng giữa hai đầu dẫn cảm biến sẽ <u>giảm đi</u>.

:Về nguyên tắc, bất kỳ '''Điện trở''' nào trong mạch đều có thể được thay thế bằng Quang trở. Vậy nên để biến đổi cường độ ánh sáng thành '''Điện áp''' cho '''Vi điều khiển''' đọc được dưới dạng tín hiệu Analog. Một Quang trở có thể <u>mắc nối tiếp</u> với một Điện trở thông thường, tạo thành một '''Bộ phân áp'''.

:Có <u>2 cách</u> để thực hiện việc này theo hình dưới đây. Sơ đồ bên trái, khi chiếu ánh sáng vào sẽ làm điện áp đầu ra tăng. Còn sơ đồ bên phải, khi chiếu ánh sáng vào sẽ làm điện áp đầu ra giảm.

[[File:Lesson6-2way-use-Photoresistor.png|700px|thumb|center|alt=2 cách sử dụng Quang trở|2 cách sử dụng Quang trở]]

:Để dễ hiểu, các bạn hãy xem Quang trở như '''Nút nhấn'''. Khi có ánh sáng chiếu vào sẽ làm nó giảm Trở kháng và dễ dẫn điện hơn, khi ấy ta có thể xem như đang <u>NHẤN NÚT</u>. Cho nên ngược lại, khi không có ánh sáng chiếu vào, ta có thể xem như đang <u>NHẢ NÚT</u>.

=== <span style=color:#314B9F>Serial Plotter?</span> ===

:'''Serial Plotter''' là một trong những công cụ trong Arduino IDE. Nó có thể nhận dữ liệu từ bo Arduino và hiển thị lên màn hình máy tính dưới <u>dạng '''Sóng (Wave)'''</u> thay vì <u>văn bản thuần</u> như '''Serial Monitor'''.

[[File:Lesson6-Serial-Plotter.png|700px|thumb|center|alt=Serial Plotter|Serial Plotter]]

:Nó có thể trực quan hóa không chỉ một dữ liệu đơn lẻ mà còn nhiều dữ liệu trong cùng một đồ thị. Trong đó, '''Trục tung (X)''' thể hiện ''"biên độ"'' dữ liệu, còn '''Trục hoành (Y)''' cập nhập dữ liệu liên tục theo ''"thời gian"''.

:Và để Serial Plotter biểu diễn đồ thị đúng ý mình, ta sẽ cần tuân theo một số <u>quy tắc</u> trong việc gửi dữ liệu từ bo Arduino lên máy tính, để phần mềm có thể diễn giải đúng được. Bài hướng dẫn chi tiết, mình có để link ở mục '''<span style=color:#108BA2>Tìm hiểu thêm!</span>'''

== '''Phần mềm''' ==

=== <span style=color:#314B9F>Arduino</span> ===

{{Tr-Info
|name= Trước khi bắt đầu:
|value=<p>
* Yêu cầu đã cài phần mềm '''Arduino IDE''' (nên cài phiên bản mới nhất đã ổn định).
* Các bạn có thể xem các bài hướng dẫn cơ bản về cách cài, cách sử dụng IDE này [[Tổng quan Arduino|'''tại đây''']] nhé.
</p>
}}

== '''Phần cứng''' ==

=== <span style=color:#314B9F>Danh sách thiết bị</span> ===

{| class="wikitable"
|+
!Tên sản phẩm
!Số lượng
|-
|[[Mạch Vietduino Uno (Arduino Uno Compatible)]]
|style="text-align: center; | 1
|-
|[[Mạch Arduino MakerEDU Shield]]
|style="text-align: center; | 1
|-
|[[Cảm biến ánh sáng quang trở MKL-S02 LDR light sensor]]
|style="text-align: center; | 1
|-
|[[Mạch led đơn MKL-M01 10mm single LED module]] '''[Trắng (White)]'''
|style="text-align: center; | 1
|-
|[https://hshop.vn/products/cap-micro-usb Cáp Micro USB]
|style="text-align: center; | 1
|-
|[https://hshop.vn/products/cap-ket-noi-makeredu-xh2-54-3wires-20cm-cable Cáp Kết Nối MakerEDU XH2.54 3Wires 20cm Cable] '''[XH2.54 - XH2.54]'''
|style="text-align: center; | 2
|}

=== <span style=color:#314B9F>Hướng dẫn kết nối</span> ===

# Gắn Shield ''"Arduino MakerEDU"'' lên bo Vietduino.
# Kết nối Module Quang trở với Shield bằng dây ''"XH2.54 <u>3Wires</u>"'' vào <mark>'''Port A1'''</mark>.
# Kết nối Module LED với Shield bằng dây ''"XH2.54 <u>3Wires</u>"'' vào <mark>'''Port D9'''</mark>.
# Kết nối bo Vietduino với máy tính thông qua cáp MicroUSB.

== '''Code''' ==

# Mở Arduino IDE.
# Vào <code>File -> New</code> (hoặc '''Ctrl+N''') tạo 1 file Arduino mới và đặt tên là ...\<code>Smart_Light.ino</code>
# Vào <code>Tool</code> để cấu hình '''Board:...''' và '''Port:...''' đúng tương ứng với bo Arduino bạn đang dùng.
# Copy đoạn Code sau và nhấp vào '''Verify (Ctrl+R)''' để IDE kiểm tra lỗi cú pháp.
# Sau khi IDE kiểm tra không có lỗi trong Code, lúc này bạn có thể nhấp '''Upload (Ctrl+U)''' để nạp Code vào bo Arduino.

=== <span style=color:#314B9F>Code Example</span> ===

{{kxncode
|name = Smart_Light.ino
|code =
<syntaxhighlight>
/* ---------------------- Giải thích kỹ thuật Phần cứng --------------------- */

/***
 * Module Quang trở ---------> Arduino (Input Analog)
 * _ CÀNG SÁNG               : ĐIỆN ÁP TIẾN VỀ 0V   (GIÁ TRỊ 0)
 * _ CÀNG TỐI                : ĐIỆN ÁP TIẾN VỀ 3,3V (GIÁ TRỊ 675)
 * |
 * _ TỨC KHI CƯỜNG ĐỘ ÁNH SÁNG THAY ĐỔI TĂNG HOẶC GIẢM
 * _ GIÁ TRỊ ĐIỆN ÁP CẢM BIẾN XUẤT RA SẼ THAY ĐỔI TỪ [0V : 3,3V]
 * _ TƯƠNG ỨNG GIÁ TRỊ ARDUINO ĐỌC ĐƯỢC TRONG PHẠM VI [0 : 675]
 * 
 * Arduino (Output Digital) -> Module LED
 * _ LOW                     : LED OFF
 * _ HIGH                    : LED ON
 */

/* -------------------------------------------------------------------------- */

#define SET_POINT 50      // Điểm sẽ thay đổi trạng thái, đơn vị (%)
#define DELTA     10      // Khoảng lệch trên/dưới cho phép tính từ "SET_POINT", đơn vị (%)

const byte photoPin = A1; // Chọn chân Analog cho cảm biến Quang trở
const byte ledPin = 9;    // Chọn chân Digital cho đèn LED

bool state;               // Biến lưu trạng thái của Quang trở

/* -------------------------------------------------------------------------- */

void setup()
{
  Serial.begin(115200);     // Khởi tạo Serial Port với Baud Rate 115.200 bps

  pinMode(photoPin, INPUT); // Đặt chân A1 là Input
  pinMode(ledPin, OUTPUT);  // Đặt chân D9 là Output

  int valuePercent = analogRead(photoPin);          // Step 1: Đọc giá trị thô của cảm biến trước
  valuePercent = map(valuePercent, 0, 675, 0, 100); // Step 2: Chuyển đổi giá trị thô sang thang đo (%)
  if(valuePercent >= SET_POINT) {state = HIGH;}     // Step 3: Chuyển đổi giá trị (%) sang thang trạng thái HIGH/LOW
  else                          {state = LOW;}      //         Nếu từ SET_POINT trở lên sẽ là HIGH, dưới SET_POINT là LOW
  digitalWrite(ledPin, state);                      // Step 4: Cập nhập trạng thái LED tương ứng với cảm biến
}

/* -------------------------------------------------------------------------- */

void loop()
{
  /* Đọc giá trị thô của cảm biến và chuyển sang thang đo (%) */
  int valuePercent = analogRead(photoPin);
  valuePercent = map(valuePercent, 0, 675, 0, 100);

  /* Luật là chỉ thay đổi trạng thái khi vượt quá "DELTA" kể từ "SET_POINT" */
  if(state)                            // Trạng thái cũ đang là HIGH
  {
    if(valuePercent < SET_POINT-DELTA) // Nên nếu ánh sáng giảm xuống dưới điểm "SET_POINT-DELTA"
    {
      state = LOW;                     // Lúc này mới được cập nhập lại trạng thái mới là LOW
      digitalWrite(ledPin, state);     // Và BẬT ĐÈN
    }
  }
  else                                 // Trạng thái cũ đang là LOW
  {
    if(valuePercent > SET_POINT+DELTA) // Nên nếu ánh sáng tăng lên trên điểm "SET_POINT+DELTA"
    {
      state = HIGH;                    // Lúc này mới được cập nhập lại trạng thái mới là HIGH
      digitalWrite(ledPin, state);     // Và TẮT ĐÈN
    }
  }

  /* Hiển thị đồ thị trực quan lên Serial Plotter */
  Serial.print(100);
  Serial.print(" ");
  Serial.print(0);
  Serial.print(" ");
  (state)?(Serial.print(SET_POINT+DELTA)):(Serial.print(SET_POINT-DELTA));
  Serial.print(" ");
  Serial.println(valuePercent);

  /* Cập nhập kiểm tra lại sau mỗi 0,01s */
  delay(10);
}
</syntaxhighlight>
}}

=== <span style=color:#314B9F>Giải thích Code</span> ===

<syntaxhighlight>
#define /*** TIỀN XỬ LÝ ***/
</syntaxhighlight>

<u>Chức năng:</u>
* Đây cũng là 1 lệnh <u>chỉ thị</u> dành cho '''Tiền xử lý'''.<br>Nó cho phép lập trình viên <u>đặt tên</u> '''(MACRO)''' cho một '''Giá trị không đổi (Constant)''' trước khi chương trình được biên dịch. Và khi bắt đầu quá trình biên dịch, trước tiên Tiền xử lý sẽ thực hiện ''"ánh xạ"'' (làm thay đổi văn bản Code) trên các MACRO này bằng các giá trị được xác định trước.

{{Tr-Info
|name= MACRO?
|value=<p>
* MACRO hiểu đơn giản là một quy tắc ''"ánh xạ"'' một giá trị đầu vào thành một giá trị đầu ra theo một quy trình đã được xác định.
</p>
}}

<u>Cú pháp:</u>
* '' #define '''Constant_Name''' '''Value''' ''

<u>Tham số:</u>
* '''Constant_Name''' - tên của MACRO được xác định.
* '''Value''' - giá trị để ''"gán"'' cho MACRO đó.

<syntaxhighlight>
const /*** ĐỊNH TÍNH ***/
</syntaxhighlight>

<u>Chức năng:</u>
* Là một '''Định tính (Qualifier)''' cho biến, làm sửa đổi <u>hành vi</u> của biến.<br>Nó làm cho một biến trở thành loại ''"chỉ đọc"'', như '''Hằng số (Constant)'''.<br>Điều này có nghĩa là biến có thể được sử dụng giống như bất kỳ biến nào khác cùng loại, nhưng giá trị của nó <u>không thể thay đổi</u>. Trình biên dịch sẽ báo lỗi nếu phát hiện bạn cố gắng thay đổi giá trị của biến trong chương trình.

<u>Cú pháp:</u>
* '' const '''type''' '''var''' = '''val'''; ''

<u>Tham số:</u>
* '''type''' - các ''"kiểu dữ liệu"''.
* '''var''' - tên biến.
* '''val''' - giá trị bạn ''"gán cố định luôn"'' cho biến đó.


----


{{Tr-Info
|name= #define và const:
|value=<p>
* Tuy cả 2 có chức năng nhìn giống như nhau, đều cho phép ta đặt tên cho một giá trị hằng số để sử dụng cái tên đó trong Code. Nhưng giữa chúng vẫn có điểm khác nhau.
* Đó là các '''MACRO''' chỉ đơn thuần là một giá trị [https://www.geeksforgeeks.org/types-of-literals-in-c-c-with-examples/ '''Literal'''] được thay thế (không phải là Biến). Chính vì vậy nó có thể được sử dụng ở bất kỳ đâu trong chương trình hoặc trong các tệp khác, mà không có sự ràng buộc hay kiểm soát.
* Còn '''const''' là một từ khóa được dùng cho Biến. Nên nó sẽ <u>được kiểm soát</u> bởi những thuộc tính của Biến đó, <u>như:</u> Phạm vi sử dụng, Thời gian tồn tại, ... cũng như bởi Trình biên dịch
</p>
}}


----


<syntaxhighlight>
byte /*** KIỂU DỮ LIỆU ***/
</syntaxhighlight>

<u>Chức năng:</u>
* Tạo một biến có kiểu dữ liệu là '''SỐ NGUYÊN KHÔNG DẤU''' để lưu trữ.<br>'''KHÔNG DẤU (Unsigned)''' nghĩa là biến này chỉ có thể lưu trữ <u>Số Nguyên Dương</u>.<br>Với '''1 Byte = 8 bit''', nó có thể lưu trữ một Số Nguyên trong phạm vi ''từ 0 đến 255 (2<sup>8</sup>-1)''.

<u>Cú pháp:</u>
* ''byte '''var''' = '''val''';''
* ''byte '''var''';''

<u>Tham số:</u>
* '''var''' - tên biến.
* '''val''' - giá trị bạn ''"gán"'' cho biến đó.

<syntaxhighlight>
if(condition)
{
  // statement(s)
}
else
{
  // statement(s)
}
</syntaxhighlight>

<u>Chức năng:</u>
* Câu lệnh <code>if</code> kiểm tra một '''Điều kiện (Condition)''' và thực hiện <u>một câu lệnh</u> hoặc <u>tập hợp các câu lệnh</u> của nó, nếu điều kiện là <code>true</code>.<br>Ngược lại, điều kiện là <code>false</code> thì sẽ thực hiện <u>một câu lệnh</u> hoặc <u>tập hợp các câu lệnh</u> của phần mở rộng <code>else</code>.

<u>Tham số:</u>
* '''condition''' - một biểu thức Boolean (có thể là <code>true</code> hoặc <code>false</code>).

<syntaxhighlight>
Serial.print(); /*** HÀM ***/
</syntaxhighlight>

<u>Chức năng:</u>
* In dữ liệu vào cổng Serial Port dưới dạng <u>văn bản ASCII</u> mà con người có thể đọc được.<br>Lệnh này có thể nhận nhiều định dạng kiểu dữ liệu (<u>như:</u> kí tự, chuỗi, số nguyên, số thực, ...) tương tự giống với lệnh <code>Serial.println()</code>.

<u>Cú pháp:</u>
* ''Serial.print('''val''');''

<u>Tham số:</u>
* '''val''' - giá trị để in (cho phép bất kì kiểu dữ liệu nào).

<u>Kiểu dữ liệu trả về:</u>
* Trả về số Byte được in ra (kiểu dữ liệu <code>size_t</code>).<br>Chức năng này là tùy chọn, bạn có thể đọc hoặc không đọc cũng được.

<syntaxhighlight>
>  /*** TOÁN TỬ ***/
>= /*** TOÁN TỬ ***/
<= /*** TOÁN TỬ ***/
<  /*** TOÁN TỬ ***/
</syntaxhighlight>

<u>Chức năng:</u>
* Là các '''Toán tử So sánh''' có <u>2 Toán hạng</u>.<br>Nó giúp ''"so sánh"'' Biến ở bên trái với Biến hoặc Hằng số ở bên phải của toán tử.

<u>Cú pháp:</u>
* '' '''x''' > '''y'''; // kết quả là <code>true</code> nếu x lớn hơn y và <code>false</code> nếu x nhỏ hơn bằng y ''
* '' '''x''' >= '''y'''; // kết quả là <code>true</code> nếu x lớn hơn bằng y và <code>false</code> nếu x nhỏ hơn y ''
* '' '''x''' <= '''y'''; // kết quả là <code>true</code> nếu x nhỏ hơn bằng y và <code>false</code> nếu x lớn hơn y ''
* '' '''x''' < '''y'''; // kết quả là <code>true</code> nếu x nhỏ hơn y và <code>false</code> nếu x lớn hơn bằng y ''

<u>Tham số:</u> → cả 2 toán hạng đều có thể là bất kì kiểu dữ liệu nào.
* '''x''' - là Biến (toán hạng bên phải).
* '''y''' - là Biến hoặc Hằng số (toán hạng bên trái).

<syntaxhighlight>
?: /*** TOÁN TỬ ***/
</syntaxhighlight>

<u>Chức năng:</u>
* Là một '''Toán tử Điều kiện''' có tận <u>3 Toán hạng</u>.<br>Nó có chức năng tương tự như câu lệnh <code>if-else</code> nhưng lại chiếm ít không gian hơn và giúp viết câu lệnh <code>if-else</code> theo cách ngắn nhất có thể.

<u>Cú pháp:</u>
* '' '''var''' = '''exp1''' ? '''exp2''' : '''exp3'''; // tương tự cấu trúc if (exp1) {var = exp2} else {var = exp3} ''
* '' '''exp1''' ? '''exp2''' : '''exp3'''; // tương tự cấu trúc if (exp1) {exp2} else {exp3} ''

<u>Tham số:</u>
* '''var''' - tên biến.
* '''exp1''' - là biểu thức được đánh giá.
* '''exp2''' - là biểu thức trả về hoặc <u>câu lệnh</u> được thực hiện nếu '''exp1''' đánh giá là <code>true</code>.
* '''exp3''' - là biểu thức trả về hoặc <u>câu lệnh</u> được thực hiện nếu '''exp1''' đánh giá là <code>false</code>.

=== <span style=color:#314B9F>Lưu đồ (Flow Chart)<span> ===

[[File:FlowChartB6.png|700px|frameless|center]]

'''Chương trình này hoạt động như thế nào?'''

Trước khi thật sự bắt đầu hoạt động.
* Ta sẽ cần đọc giá trị Analog từ cảm biến Quang trở lần đầu tiên để lấy mẫu.
* Từ giá trị Analog đọc được, ta chuyển đổi sang thang đo mới, với đơn vị (%).
* Và lần nữa chuyển đổi tiếp sang thang đo khác, chỉ còn 2 giá trị là <code>HIGH</code> và <code>LOW</code>. Nhờ giá trị (%) nên ta dễ dàng xác định <u>trạng thái</u> của Quang trở qua điểm '''SetPoint'''.
* Sau khi đã xác định được trạng thái của Quang trở rồi, ta có thể quyết định bật LED hay tắt LED tùy theo nhu cầu sử dụng.

Kể từ lần lấy mẫu đầu tiên, chương trình mới thực sự bắt đầu hoạt động.
* Từ những lần sau quá trình cứ lặp lại như trên. Nhưng sẽ có thêm một <u>quy tắc</u> để tránh trường hợp mỗi khi giá trị đọc từ cảm biến dao động nhỏ quanh điểm SetPoint, làm đèn LED bật tắt liên tục.
* Để khắc phục ta sử dụng thêm giá trị '''Delta''' kết hợp với <u>luật:</u> ''"Là chỉ chấp nhận trạng thái mới của Quang trở (tức thay đổi trạng thái LED) chỉ khi giá trị (%) vượt quá khoảng Delta của ngưỡng trên hoặc dưới tính từ điểm SetPoint"''.

{{Tr-Info
|name= Tip:
|value=<p>
* Điểm tiện lợi của '''SetPoint''' và '''Delta''' là ta dễ dàng tinh chỉnh lại trong code cho phù hợp với vùng ánh sáng xung quanh ở môi trường hiện tại.
* Ngoài ra, các bạn có thể bật đồ thị '''Serial Plotter''' để xem trực quan quá trình thiết bị hoạt động như thế nào. Bấm vào <code>Tool -> Serial Plotter</code>, hoặc nhấn phím tắt '''Ctrl+Shift+L''' (nhớ chọn đúng Baudrate theo code).
</p>
}}

=== <span style=color:#314B9F>Kết quả Demo<span> ===

{{Tr-Warning
|name = Vấn đề nguồn:
|value = <p>
* Các bạn lưu ý, bất cứ ứng dụng nào chúng ta có dùng đến hàm <code>analogRead()</code>, để kết quả chạy đúng theo Code. Ta phải cấp nguồn riêng cho các board Arduino ở <u>jack DC</u>, hoặc chí ít phải đảm bảo nguồn cấp qua <u>cổng USB</u> đúng '''5V!'''
* Vì thực tế hàm này trả về giá trị <u>MAX</u> '''1.023''' bằng với giá trị điện áp đang cấp nuôi cho Vi Điều Khiển trên bo Arduino, chứ không phải là 5V.
* Nên khi nguồn điện áp này không đúng 5V có thể làm chương trình trả về kết quả sai số nhỏ, hay xuất hiện những lỗi không mong muốn, thậm chí hoạt động sai!
</p>
}}

Nếu mình đã cấp đủ nguồn rồi, thì ...

{{Tr-Done
|name= Successful:
|value=<p>
* Đèn LED chỉ thay đổi từ OFF sang ON, khi ánh sáng môi trường xung quanh giảm đi, và chạm ngưỡng dưới điểm '''(SetPoint - Delta)'''.
* Còn ngược lại, khi ánh sáng môi trường xung quanh nhiều, làm chạm qua ngưỡng '''(SetPoint + Delta)'''.
</p>
}}

Các bạn có thể xem chương trình sẽ hoạt động như thế nào theo video dưới đây nhé.

<mark>!!!</mark> nhúng 1 clip youtube, để xem video trực tiếp trên trang này. Dùng extension <iframe> cho MediaWiki.

=== <span style=color:#314B9F>Gợi ý mở rộng<span> ===

:_ Ta có thể thay đèn LED bằng <u>Relay</u> → để bật tắt các bóng đèn điện hay các thiết bị điện trong nhà.

:_ Kết hợp thêm <u>Module RealTime</u> → để tự động tinh chỉnh thông số sao cho hoạt động phù hợp với từng khung giờ sinh hoạt trong ngày.

:_ Kết hợp các thiết bị như <u>Dimmer</u> -> để theo dõi độ sáng của đèn bàn học hay góc làm việc từ đó điều chỉnh độ sáng đèn tự động ở một mức độ ổn định → giúp mắt mình đỡ mỏi, dễ chịu hơn.

:_ Làm ứng dụng theo dõi cường độ ánh sáng trong phòng → từ đó điều chỉnh rèm cửa tự động hay cửa miệng giếng trời → giúp luôn duy trì một lượng ánh sáng ổn định cho cả căn nhà.

:_ Làm hệ thống ánh sáng sân vườn tự động → bật đèn dần khi trời tối và tắt đèn dần khi trời sáng.

:_ Làm hệ thống theo dõi hướng mặt trời, để điều chỉnh hướng nhận được ánh sáng nhiều nhất có thể → cho các tấm pin năng lượng mặt trời, từ đó giúp tối ưu hiệu suất tạo năng lượng. Hay điều chỉnh hướng thấu kính tự động → để làm bộ đun nước nóng bằng mặt trời.

:_ ...

== '''Tìm hiểu thêm''' ==

<span style=color:#0E9447><u>'''Về Quang trở và các Cảm biến tương tự khác:'''</u></span> [https://www.etechnog.com/2021/06/photoresistor-vs-photodiode-vs-phototransistor.html | Photoresistor VS Photodiode VS Phototransistor].

<span style=color:#0E9447><u>'''Về cách sử dụng đồ thị Serial Plotter:'''</u></span> [https://arduinogetstarted.com/tutorials/arduino-serial-plotter | Arduino - Serial Plotter].

<span style=color:#0E9447><u>'''Ngôn ngữ lập trình Arduino:'''</u></span> [https://www.arduino.cc/reference/en/ | Language - Arduino Reference].